0. 写在前面

这一系列记录我在完成 MIT 操作系统课程过程中的笔记、问题和心得。6.828 是 MIT 的操作系统课程,其 lab 是一个简单的 xv6 系统,我们需要完成其中一部分模块来实现操作系统的部分功能。例如:bootloader、内存管理、进程调度等等。本篇博客对应的是 lab1 的部分。

1. 实验介绍

lab 1 的内容是有关 PC bootstrap 的。这个实验分为三个阶段:BIOS 启动、BootLoader、进入内核。最终,我们能看到第一个版本的 xv6 内核。

2. PC 的物理地址空间

为了了解整个 PC 的启动过程,我们先需要了解整个 PC 的物理内存空间布局:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
+------------------+ <- 0xFFFFFFFF (4GB)
| 32-bit |
| memory mapped |
| devices |
| |
/\/\/\/\/\/\/\/\/\/\
/\/\/\/\/\/\/\/\/\/\
| |
| Unused |
| |
+------------------+ <- depends on amount of RAM
| |
| |
| Extended Memory |
| |
| |
+------------------+ <- 0x00100000 (1MB)
| BIOS ROM |
+------------------+ <- 0x000F0000 (960KB)
| 16-bit devices, |
| expansion ROMs |
+------------------+ <- 0x000C0000 (768KB)
| VGA Display |
+------------------+ <- 0x000A0000 (640KB)
| |
| Low Memory |
| |
+------------------+ <- 0x00000000

其中,为了向后兼容 16 位 8086(在实模式下寻址空间为 1MB),前 640kB 的部分称之为“低内存”,BIOS 被装载到 1MB 以下的空间。

3. 用 GDB 调试 BIOS 的执行过程

前后一些非关键的代码省略,这里列出 BIOS 所做的部分工作:

1
2
3
4
5
6
7
8
9
10
11
12
.......
[f000:d15f] 0xfd15f: cli # 清除标志位
[f000:d160] 0xfd160: cld # 清除串传送方向标志位
[f000:d161] 0xfd161: mov $0x8f,%eax
[f000:d167] 0xfd167: out %al,$0x70 # 开启NMI
[f000:d169] 0xfd169: in $0x71,%al
[f000:d16b] 0xfd16b: in $0x92,%al
[f000:d16d] 0xfd16d: or $0x2,%al
[f000:d16f] 0xfd16f: out %al,$0x92 # 开启 A20 地址线
[f000:d171] 0xfd171: lidtw %cs:0x6ab8 # 装载IDT、GDT
[f000:d177] 0xfd177: lgdtw %cs:0x6a74
........

4. 调试 BootLoader

一般情况下,硬盘按照 512 byte 为单位被分为不同的扇区。扇区是磁盘数据传输的最小粒度。每一次原始的读写操作必须是一整个或者多个扇区为单位,而且需要对齐到扇区的边界。如果一个磁盘是可以引导的,第一个扇区叫做引导扇区。当 BIOS 找到可被引导的磁盘时,它会将 BootLoader 加载到物理内存地址的 0x7c00~0x7dff 的区域。然后通过一条 jmp 指令跳转到这一地址。

BootLoader 的工作主要有两个:

  1. 将处理器从实模式转换到 32 位的保护模式。
  2. 从磁盘中装载内核。

我们不妨一看 boot.S 源码,来一窥 bootloader 的工作。

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
#include <inc/mmu.h>
# Start the CPU: switch to 32-bit protected mode, jump into C.
# The BIOS loads this code from the first sector of the hard disk into
# memory at physical address 0x7c00 and starts executing in real mode
# with %cs=0 %ip=7c00.
.set PROT_MODE_CSEG, 0x8 # kernel code segment selector
.set PROT_MODE_DSEG, 0x10 # kernel data segment selector
.set CR0_PE_ON, 0x1 # protected mode enable flag
.globl start
start:
.code16 # Assemble for 16-bit mode
cli # Disable interrupts
cld # String operations increment
# Set up the important data segment registers (DS, ES, SS).
xorw %ax,%ax # Segment number zero
movw %ax,%ds # -> Data Segment
movw %ax,%es # -> Extra Segment
movw %ax,%ss # -> Stack Segment
# Enable A20:
# For backwards compatibility with the earliest PCs, physical
# address line 20 is tied low, so that addresses higher than
# 1MB wrap around to zero by default. This code undoes this.
seta20.1:
inb $0x64,%al # Wait for not busy
testb $0x2,%al
jnz seta20.1
movb $0xd1,%al # 0xd1 -> port 0x64
outb %al,$0x64
seta20.2:
inb $0x64,%al # Wait for not busy
testb $0x2,%al
jnz seta20.2
movb $0xdf,%al # 0xdf -> port 0x60
outb %al,$0x60
# Switch from real to protected mode, using a bootstrap GDT
# and segment translation that makes virtual addresses
# identical to their physical addresses, so that the
# effective memory map does not change during the switch.
lgdt gdtdesc
movl %cr0, %eax
orl $CR0_PE_ON, %eax
movl %eax, %cr0
# Jump to next instruction, but in 32-bit code segment.
# Switches processor into 32-bit mode.
ljmp $PROT_MODE_CSEG, $protcseg
.code32 # Assemble for 32-bit mode
protcseg:
# Set up the protected-mode data segment registers
movw $PROT_MODE_DSEG, %ax # Our data segment selector
movw %ax, %ds # -> DS: Data Segment
movw %ax, %es # -> ES: Extra Segment
movw %ax, %fs # -> FS
movw %ax, %gs # -> GS
movw %ax, %ss # -> SS: Stack Segment
# Set up the stack pointer and call into C.
movl $start, %esp
call bootmain
# If bootmain returns (it shouldn't), loop.
spin:
jmp spin
# Bootstrap GDT
.p2align 2 # force 4 byte alignment
gdt:
SEG_NULL # null seg
SEG(STA_X|STA_R, 0x0, 0xffffffff) # code seg
SEG(STA_W, 0x0, 0xffffffff) # data seg
gdtdesc:
.word 0x17 # sizeof(gdt) - 1
.long gdt # address gdt

3. 进入内核

内核将自己映射至了非常高的虚拟地址空间,比如0xf0100000,这是为了将低地址留给用户程序去使用。

有关虚拟内存映射的问题将在第二个实验中完成。

4. 栈

esp是栈指针,是cpu机制决定的,push、pop指令会自动调整esp的值;

ebp只是存取某时刻的esp,这个时刻就是进入一个函数内后,cpu会将esp的值赋给ebp,此时就可以通过ebp对栈进行操作,比如获取函数参数,局部变量等,实际上使用esp也可以;

TBC。